#!/bin/csh -f

echo -n "Getting converter types..."
	set files
	if ( -e /LocalLibrary/Converters ) then
		set files=( `echo "ls /LocalLibrary/Converters/*.bcvt 2> /dev/null" | sh` )
	endif
	if ( -e /NextLibrary/Converters ) then
		set files=( $files `echo "ls /NextLibrary/Converters/*.bcvt 2> /dev/null" | sh` )
	endif
	if ( -e $HOME/Library/Converters ) then
		set files=( $files `echo "ls $HOME/Library/Converters/*.bcvt 2> /dev/null" | sh` )
	endif
echo "done."

echo -n "Building new iconheader..."
	echo "F	GraphicsWorkshop.app	GraphicsWorkshop	app" >! tmp.iconheader
	echo "F	GraphicsWorkshop	GraphicsWorkshop	app" >> tmp.iconheader
	echo "S	bcvt	GraphicsWorkshop	bcvt" >> tmp.iconheader
	echo "S	tools	GraphicsWorkshop	tools" >> tmp.iconheader
	echo "S	controls	GraphicsWorkshop	controls" >> tmp.iconheader
	foreach file ($files)
		set name = `basename $file | awk -F. '{print $1}'`
		if ( $name != converter ) then
			echo "S	$name	GraphicsWorkshop	unknown" >> tmp.iconheader
			set name = `echo $name | tr a-z A-Z`
			echo "S	$name	GraphicsWorkshop	unknown" >> tmp.iconheader
		endif
	end
echo "done."

echo -n "Removing duplicate entries..."
	sort -u tmp.iconheader >! tmp
	mv tmp tmp.iconheader
echo "done."

echo -n "Adding new icon header to GraphicsWorkshop..."
	segedit GraphicsWorkshop.app/GraphicsWorkshop -r __ICON __header tmp.iconheader -o G2
	mv G2 GraphicsWorkshop.app/GraphicsWorkshop
echo "done."

rm tmp.iconheader